Graphviz: Dabbling With Groovy Builders

Ok, so I'm up late and fancy playing around with Groovy builders. How about a builder for graphviz dot files I think to myself? So I took the dot example (image) and made it builder friendly. To do so I changed:

digraph unix {
  size="6,6";
  node [color=lightblue2, style=filled];
  "5th Edition" -> "6th Edition";
  ...

To:

new DotBuilder().dot {
  size "6,6";
  node( [color:'lightblue2', style:'filled'] );
  from "5th Edition"; to "6th Edition";
  ...

This code then exercises the required builder and displays a dot graph image in a swing frame (using the swing builder):

import groovy.swing.SwingBuilder
import java.awt.BorderLayout

class DotBuilderExample {

  static void main(args) {
    def image = new DotBuilder().dot {
      size "6,6";
      node( [color:'lightblue2', style:'filled'] );
      from "Got Java"; to "Got Groovy"; to "Got DotBuilder";
      from "Got Graphviz"; to "Got DotBuilder";
    }.image
  
    def frame = new SwingBuilder().frame(title:'Example Dot', size:[300,300]) {
      borderLayout()
      label(icon:imageIcon(image))
    }
    frame.pack()
    frame.show()
  }
}

The code for the builder is as follows:

import groovy.util.BuilderSupport
import javax.imageio.ImageIO

class DotBuilder extends BuilderSupport {
  private def out
  private def outTarget
  private def from, to
  
  DotBuilder() {
    outTarget = new StringWriter()
    out = new PrintWriter(outTarget)
  }
  
  protected void setParent(Object parent, Object child) { }
    
  protected Object createNode(Object name) {
    if (name == 'dot') return this
  }
    
  protected Object createNode(Object name, Object value) {
    if (name == 'from') {
      from = value
    } else if (name == 'to') {
      out.println """"$from" -> "$value";"""
      from = value // lets us chain them
    } else {
      out.println """$name="$value";"""
    }
  }
    
  protected Object createNode(Object name, Map attributes) {
    out.println """$name [${attributes.collect { "$it.key=$it.value" }.join(", ")}];"""
  }
      
  protected Object createNode(Object name, Map attributes, Object value) { }
    
  protected void nodeCompleted(Object parent, Object node) { }

  def getImage() {
    Process p = Runtime.getRuntime().exec("dot -Tgif")
    p.outputStream.withStream { stream ->
      stream << "digraph unix { $outTarget }"
    }
    p.waitFor()
    ImageIO.read(p.inputStream)
  }
}

Note: There are in fact closing triple quotes on the long line above.